Основы программирования — второй семестр 08-09; Михалкович С.С.; III часть
Лекция 5
Содержание
Рекурсия
Введение
Рекурсией называется определение объекта через такой же объект.
Пример.
(1) <Список> ::= <Число>
|<Список> ',' <Число>
В данном примере рекурсивной частью определения является "<Список> ',' <Число>".
Замечание 1. Рекурсивное определение, будучи конечным, определяет бесконечное множество объектов.
Заметим также, что <Список> можно определить и по-другому:
(2) <Список> ::= <Число>
|<Число> ',' <Список>
Определение (1) называют леворекурсивным,
а (2) — праворекурсивным.
Замечание 2. В рекурсивном определении обязательно (!!!) должна присутствовать нерекурсивная часть.
Рекурсивное определение может быть косвенным:
- по одной из ветвей рекурсивного определения упоминается объект, в определении которого, в свою очередь, по одной из ветвей определяется исходный объект.
В программировании под рекурсией понимается:
- вызов из подпрограммы самой себя (прямая рекурсия)
- вызов из подпрограммы другой подпрограммы, которая вызывает исходную (косвенная рекурсия)
При косвенной рекурсии обязательно использование опережающего объявления с помощью ключевого слова forward:
procedure q; forward; // опережающее определение
procedure p;
begin
...
q;
...
end;
procedure q;
begin
...
p;
...
end;Простые примеры использования рекурсии
Пример 1.
procedure p(i: integer);
begin
write(i, ' ');
p(i + 1);
end;При вызове этой процедуры произойдет рекурсивное зацикливание, т.к. рекурсивный вызов производится безусловно.
Вывод. Чтобы рекурсивного зацикливания не произошло, рекурсивный вызов должен происходить не безусловно, а по какому-то условию, которое всякий раз меняется и при каком-то рекурсивном вызове становится ложным (так называемое условие продолжения рекурсии).
Исправим нашу процедуру в соответствии со сделанным выводом:
procedure p(i: integer);
begin
write(i, ' ');
if i < 5 then
p(i + 1);
end;При вызове p(0) будет выведено:
0 1 2 3 4 5
Графически, рекурсивные вызовы можно изобразить так:
Процесс последовательных рекурсивных вызовов подпрограммы из самой себя называется рекурсивным спуском.
Процесс возврата из рекурсивных вызовов называется рекурсивным возвратом.
В данном примере числа выводятся на рекурсивном спуске (т.е. в прямом порядке).
Однако, чтобы действия выполнялись в обратном порядке, их нужно вызывать на рекурсивном возврате.
Пример 2. Вывести
0 1 2 3 4 5 4 3 2 1 0
Решение:
procedure p(i: integer);
begin
write(i, ' ');
if i < 5 then then
begin
p(i + 1);
write(i, ' ');
end;
end;Максимальная глубина рекурсивных вызовов называется глубиной рекурсии.
Текущая глубина называется текущим уровнем рекурсии.
Замечание. Чем больше глубина рекурсии, тем больше накладные расходы по памяти.
Графические изображения рекурсивных вызовов
Одно графическое изображение у нас уже было. Вспомним его:
procedure p(i: integer);
begin
write(i, ' ');
if i < 5 then
p(i + 1);
end;
Рассмотрим более детально вызов p(0) процедуры
procedure p(i: integer);
begin
write(i, ' ');
if i < 2 then
p(i + 1);
end;Вспомним, что:
- Программный стек — это непрерывная область памяти, выделяемая программе для помощи в вызове подпрограмм.
- При каждом вызове подпрограммы на стек кладется её ЗА, а при возврате — снимается со стека.
Т.о. на стеке фактически хранятся все значения переменной i.
Замечание 1. Поскольку при каждом рекурсивном вызове на стек помещается ЗА, то при большой глубине рекурсии программный стек может переполниться, и программа завершится с ошибкой.
Это произойдет тем быстрее, чем больше суммарный объем формальных параметров и локальных переменных.
Поэтому следующий код — очень плохой!!!
procedure p(i: integer);
var a : array[1..1000] of real;
begin
...
p(i + 1);
...
end;Замечание 2. Накладные расходы на помещение на стек ЗА, снятие ЗА со стека, а также присваивание значений формальным параметрам на стеке достаточно велики.
Поэтому если имеется простое нерекурсивное решение (итерационное), то следует использовать именно его.
Замечание 3. НЕ любую рекурсию можно заменить итерацией.
Примеры использования рекурсии
Пример 1. Найти n! = n(n - 1)(n - 2)...2*1
Очевидно, определить n! можем следующим образом:
- <math>f(n) = \begin{cases} n (n - 1), & n > 0 \\ 1, & n = 0 \end{cases}</math>
Тогда решение имеет вид:
function nfact(n: integer): integer;
begin
if n = 0 then
Result := 1
else
Result := n * nfact(n - 1);
end;Однако, заметим, что возвращаемое значение не определено для n < 0.
Как минимум, можно заменить условие n = 0 на n <= 0, но, в таком случае, мы получим неверный результат, т.к. факториал вообще не определен для отрицательных чисел.
Очевидно, необходимо с помощью утверждения проверить корректность входного параметра (Assert(n >= 0)). Но его использование при каждом рекурсивном вызове накладно. Поэтому можно "обернуть" рекурсивную подпрограмму, например, так:
function nfact(n: integer): integer;
function nfactRecur(n: integer): integer;
begin
if n = 0 then
Result := 1
else
Result := n * nfact(n - 1);
end;
begin
Assert(n >= 0);
Result := nfactRecur(n);
end;Глубина рекурсии этого алгоритма равна n.
Пример 2. Найти an.
Дадим рекурсивное определение:
- <math>f(n) = \begin{cases} (a^{\frac{n}{2}})^2, & \mbox{if }n\mbox{ is even}, n > 0
\\ a a^{n-1}, & \mbox{if }n\mbox{ is odd}, n > 0 \\ 1, & n = 0 \\ \frac{1}{a^n}, & n < 0\end{cases}</math>
function power(a: real; n: integer): real;
begin
if n = 0 then
Result := 1
else if n < 0 then
Result := 1 / power(a, -n)
else // n > 0
if n mod 2 = 0 then
Result := sqr(power(a, n div 2))
else
Result := a * power(a, n - 1);
end;Глубина рекурсии равна:
- log2n — в лучшем случае
- 2log2n — в худшем
Лекция 6
Пример 3. Нахождение минимального элемента в массиве.
Определить этот элемент можем как минимальный(один элемент, минимальный из массива без этого элемента), т.е. рекурсивное определение следующее:
- <math>minElem(A, n) = \begin{cases} A[n-1], & n = 1
\\ min(\; minElem(A, \; n - 1),\; A[n - 1]\;), & n > 1\end{cases}</math> В соответствии с этим имеем решение:
function MinElem(A: array of integer; n: integer): integer;
begin
if n = 1 then
Result := A[0]
else
Result := min(MinElem(A, n-1), A[n-1]));
end;Глубина рекурсии равна n - 1.
Ясно, что это не очень хороший результат.
Можно значительно уменьшить глубину, если искать минимальный среди примерно равных частей массива.
Т.е. нужно поделить массив пополам, найти в каждой половине минимальные элементы и сравнить их. Поиск в половине осуществляется подобным же образом, и деление производится до тех пор, пока в подмассиве не останется один элемент.
Можно еще немного оптимизировать этот алгоритм — если в подмассиве два элемента, достаточно вернуть минимальный из них.
Теперь знания количества элементов недостаточно: необходимо знать, среди каких элементов массива вести поиск. Поэтому будем в качестве параметров передавать левую (l) и правую (r) границы подмассивов.
Дадим новое рекурсивное определение:
- <math>minElem(A, l, r) = \begin{cases} A[l], & l = r
\\ min(A[l],\; A[r]), & r - l = 1 \\ min(\; minElem(A,\; l, \; (l + r) \; div\; 2), \; minElem( A, \; (l + r)\; div\; 2 + 1,\; r) \;), & l - r > 1\end{cases}</math> Решение:
function MinElem(a: array of integer; l, r: integer): integer;
begin
if l = r then // если всего один элемент
Result := a[l]
else if r - l = 1 then // если ищем минимум из двух элементов
Result := min(a[l], a[r])
else
begin
var mid := (l + r) div 2;
Result := min(MinBinR(a, l, mid), MinBinR(a, mid+1, r));
end;
end;Глубина рекурсии такого алгоритма уже примерно равна log2n (по количеству делений).
Пример 4. Вывод односвязного линейного списка на экран.
Вспомним, как выглядит список:
Решение:
procedure Print<T>(h: Node<T>);
begin
if h = nil then
exit;
write(h.data, ' ');
Print(h.next);
end;Глубина рекурсии равна длина списка - 1
Рекурсия называется концевой, если рекурсивный вызов является последним в подпрограмме.
Концевая рекурсия наиболее легко превращается в итеративный алгоритм:
while h <> nil do
begin
write(h.data, ' ');
h := h.next;
end;Доказательство завершимости рекурсии
Добавим к рекурсивной процедуре целый параметр n:
p(n, ...);
Если при каждом рекурсивном вызове параметр n уменьшается получим вызовы
p(n)
p(n - 1)
p(n - 2)
p(n - 3)
И если рекурсия завершается при n <= 0, то это служит доказательством завершимости рекурсии.
Действительно, на каждом следующем уровне рекурсии n становится меньше.
Поскольку при n <= 0 рекурсивных вызовов нет, то число рекурсивных вызовов конечно.
Утверждать, что рекурсия завершима, можно не всегда.
Пример.
procedure p(n);
begin
if n <= 0 then
exit
else
p(Random(2 * n) - n + 1);
end;Формы рекурсивных подпрограмм
1. Действие выполняется на рекурсивном спуске
p(n)
S(n)
if B(n) then
p(n - 1)
2. Действие выполняется на рекурсивном возврате
p(n)
if B(n) then
p(n - 1)
S(n)
3. Действие выполняется и на рекурсивном спуске и на рекурсивном возврате
p(n)
S1(n)
if B(n) then
p(n - 1)
S<supb1</sub>
4. Каскадная рекурсия
p(n)
S(n)
if B1(n) then
p(n - 1)
if B2(n) then
p(n - 1)
Эта рекурсия называется каскадной, т.к. каждый вызов подпрограммы может порождать несколько рекурсивных вызовов (каскад).
Во всех вышеперечисленных случаях рекурсию можно заменить итерацией.
5. Удаленная рекурсия:
function f(i: integer): integer;
begin
if B1(n) then
Result := ...
else
Result := f(f(i-1));
end;
Замечание. Теоретически доказано, что такую рекурсию заменить итерацией нельзя.
Примером удаленной рекурсии служит Функция Аккермана:
- <math>A(m,\;n)=\begin{cases}n+1,&m=0;
\\A(m-1,\;1),&m>0,\; n = 0; \\A(m-1,\;A(m,\;n-1)),& m > 0,\; n > 0.\end{cases}</math>
Примеры плохого и хорошего использования рекурсии
<xh4>Пример плохого использования рекурсии - числа Фибоначчи</xh4> Числа Фибоначчи задаются следующим рекуррентным соотношением:
- <math>F_1 = 1,\quad F_2 = 1,\quad F_{n+1} = F_n + F_{n-1} \quad n\in\mathbb{N}.</math>
Мы уже вычисляли их с помощью циклов. Возможно рекурсивное (плохое!) решение:
function Fib(n: integer): integer;
begin
if (n = 1) or (n = 2) then
Result := 1
else
Result := Fib(n - 1) + Fib(n - 2);
end;Вот что произойдет при вызове Fib(7):
дерево рекурсивных вызовов
Как видим, одни и те же числа вычисляются по несколько раз:
- Fib(7): 1
- Fib(6): 1
- Fib(5): 2
- Fib(4): 3
- Fib(3): 5
- Fib(2): 8
Алгоритм можно улучшить, использовав массив, первоначально заполненный нулями.
При первом вычислении fib(n) будем заполнять соответствующий элемент, а при всех последующих — просто обращаться к его значению.
var F: array[1..1000] of integer;
function Fib(n: integer): integer;
begin
if F[n] <> 0 then
Result := F[n]
else if (n = 1) or (n = 2) then
begin
Result := 1;
F[n] := 1;
end
else
begin
Result := Fib(n - 1) + Fib(n - 2);
F[n] := Result;
end;
end;<xh4>Пример хорошего использования рекурсии - ханойские башни</xh4>
Задача состоит в следующем:
Даны три стержня. На первом лежат n дисков разного радиуса при условии, что ни один диск бОльшего радиуса не лежит на диске мЕньшего радиуса.
Hеобходимо перенести диски с первого стержня на третий, пользуясь вторым, при условии:
- за один ход можно переносить только один диск
- меньший диск должен лежать на большем
Идея алгоритма такая:
перекладываем n-1 диск с исходного стержня на вспомогательный оставшийся диск перекладываем на требуемый стержень лежащие на вспомогательном стержне диски перекладываем на требуемый диск
Т.о. имеем простое рекурсивное решение:
procedure MovePiramid(n: integer; f, t, w : integer);
begin
if n = 0 then
exit;
MovePiramid(n - 1, f, w, t);
writelnFormat('Переложить диск с {0} на {1}', f, t);
MovePiramid(n - 1, w, t, f);
end;Быстрая сортировка
Алгоритм быстрой сортировки (разновидность алгоритма "разделяй и влавствуй") состоит из двух этапов:
1. Выбор некоторого элемента массива x и разделение массива на две части так, что в первой оказываются все элементы <= x, а в о второй — >= x
2. Рекурсивное применение нашего алгоритма к полученным частям
Очевидно, алгоритм будет работать тем быстрее, чем на более равные части мы будем делить массив (в идеале — каждый раз пополам).
Поэтому мы должны стремиться выбрать элемент x так, чтобы примерно половина элементов массива была <= его, и, соответственно, вторая половина — >=. С другой стороны, выбор x не должен занимать много времени и, по крайней мере, не зависеть от n — размера массива).
Мы будем использовать простейший способ выбора x — в качестве него использовать первый элемент.
На следующей анимации представлен пример применения алгоритма быстрой сортировки к массиву
4 1 7 3 2 9 5 8 6
Все элементы A[0]..A[q] меньше или равны x, а все элементы A[q+1]..A[n-1]
procedure QuickSort(A: array of integer);
// Partition - разделение A[l]..A[r] на части A[l]..A[q] <= A[q+1]..A[r]
function Partition(l,r: integer): integer;
begin
var i := l - 1;
var j := r + 1;
var x := A[l];
while True do
begin
repeat
i += 1;
until A[i]>=x;
repeat
j -= 1;
until A[j]<=x;
if i<j then
Swap(A[i],A[j])
else
begin
Result := j;
exit;
end;
end;
end;
// Сортировка частей
procedure Sort(l,r: integer);
begin
if l>=r then exit;
var j := Partition(l,r);
Sort(l,j);
Sort(j+1,r);
end;
begin
Sort(0,a.Length-1)
end;